Shopify Functions

Overview

Namespace urn:ShopifyFunctions
Available since Zynk Workflow 2023.6.2

This article will outline how to implement the XSLT functions that we have made available for our Shopify library. As shown below, you can call methods with or without a connection. If you do not specify a connection, the default connection will be used.

You can make use of the Shopify functions by including the following declaration in your XSLT document:

<xsl:stylesheet 
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    xmlns:Shopify="urn:ShopifyFunctions"> <!-- define the ShopifyFunctions argument -->

    <!-- transformation -->

</xsl:stylesheet>

Functions

The following methods can each be called with, or without, a connection identifier. If you do not provide a connection identifier, the default connection will be used.

The function will attempt to parse the connection identifier as a GUID (i.e the connection id), and if that is not successful, it will match to an existing connection based on the connection title.

• GetCustomer(string recordIdentifier)
• GetCustomer(string connectionIdentifier, string recordIdentifier)
• GetOrder(string recordIdentifier)
• GetOrder(string connectionIdentifier, string recordIdentifier)
• GetProduct(string recordIdentifier)
• GetProduct(string connectionIdentifier, string recordIdentifier)
• GetVariant(string recordIdentifier)
• GetVariant(string connectionIdentifier, string recordIdentifier)

Example

Input

<Data>
    <CustomerData>
        <Datum>
            <Id>1</Id> <!-- This customer id does not exist, so an error will be logged to the Zynk UI and the error XPath will be returned -->
        </Datum>
        <Datum>
            <Id>6260062584921</Id>
        </Datum>
        <Datum>
            <Id>3</Id> <!-- This customer id does not exist, so an error will be logged to the Zynk UI and the error XPath will be returned -->
        </Datum>
    </CustomerData>
    <OrderData>
        <Datum>
            <Id>4524119621721</Id>
        </Datum>
    </OrderData>
    <ProductData>
        <Datum>
            <Id>4430175862873</Id>
        </Datum>
    </ProductData>
</Data>

XSLT

<xsl:stylesheet 
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    xmlns:sf="urn:ShopifyFunctions"> <!-- define the ShopifyFunctions argument -->

    <xsl:output indent="yes"/>

    <xsl:template match="/">
        <Company>
            <Customers>
                <xsl:for-each select="Data/CustomerData/Datum">
                    <xsl:call-template name="Customer"/>
                </xsl:for-each>
            </Customers>
            <Orders>
                <xsl:for-each select="Data/OrderData/Datum">
                    <xsl:call-template name="Order"/>
                </xsl:for-each>
            </Orders>
            <Products>
                <xsl:for-each select="Data/ProductData/Datum">
                    <xsl:call-template name="Product"/>
                </xsl:for-each>
            </Products>
        </Company>
    </xsl:template>

    <xsl:template name="Customer">
        <Customer>
            <xsl:copy-of select="Id"/>

            <xsl:variable name="ShopifyCustomer" select="msxsl:node-set(sf:GetCustomer('Zynk Software Ltd (Shopify)', Id))"/>

            <CompanyName>
                <xsl:choose>
                    <xsl:when test="count($ShopifyCustomer/Errors/Error) &gt; 0">
                        <xsl:copy-of select="$ShopifyCustomer"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="concat($ShopifyCustomer/customer/first-name, ' ', $ShopifyCustomer/customer/last-name)"/>
                    </xsl:otherwise>
                </xsl:choose>
            </CompanyName>
            <!-- <Dump>
                <xsl:copy-of select="msxsl:node-set($ShopifyCustomer)"/>
            </Dump> -->
        </Customer>
    </xsl:template>


    <xsl:template name="Order">
        <Order>
            <xsl:copy-of select="Id"/>

            <xsl:variable name="ShopifyOrder" select="msxsl:node-set(sf:GetOrder('Zynk Software Ltd (Shopify)', Id))"/>

            <Name>
                <xsl:choose>
                    <xsl:when test="count($ShopifyOrder/Errors/Error) &gt; 0">
                        <xsl:copy-of select="$ShopifyOrder"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="$ShopifyOrder/order/name"/>
                    </xsl:otherwise>
                </xsl:choose>
            </Name>
            <!-- <Dump>
                <xsl:copy-of select="msxsl:node-set($ShopifyOrder)"/>
            </Dump> -->
        </Order>
    </xsl:template>

    <xsl:template name="Product">
        <Product>
            <xsl:copy-of select="Id"/>

            <xsl:variable name="ShopifyProduct" select="msxsl:node-set(sf:GetProduct('Zynk Software Ltd (Shopify)', Id))"/>

            <Name>
                <xsl:choose>
                    <xsl:when test="count($ShopifyProduct/Errors/Error) &gt; 0">
                        <xsl:copy-of select="$ShopifyProduct"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="$ShopifyProduct/product/title"/>
                    </xsl:otherwise>
                </xsl:choose>
            </Name>
            <!-- <Dump>
                <xsl:copy-of select="msxsl:node-set($ShopifyProduct)"/>
            </Dump> -->
        </Product>
    </xsl:template>
</xsl:stylesheet>

Output

<?xml version="1.0" encoding="utf-8"?>
<Company xmlns:msxsl="urn:schemas-microsoft-com:xslt" xmlns:sf="urn:ShopifyFunctions">
  <Customers>
    <Customer>
      <Id>1</Id>
      <CompanyName>
        <Errors>
          <Error xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
            <Message>Not Found</Message>
          </Error>
        </Errors>
      </CompanyName>
    </Customer>
    <Customer>
      <Id>6260062584921</Id>
      <CompanyName>Joseph Harrison</CompanyName>
    </Customer>
    <Customer>
      <Id>3</Id>
      <CompanyName>
        <Errors>
          <Error xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
            <Message>Not Found</Message>
          </Error>
        </Errors>
      </CompanyName>
    </Customer>
  </Customers>
  <Orders>
    <Order>
      <Id>4524119621721</Id>
      <Name>#1087</Name>
    </Order>
  </Orders>
  <Products>
    <Product>
      <Id>4430175862873</Id>
      <Name>1 X BOX LA PERRUCHE SUGAR CUBES (WHITE/BROWN)</Name>
    </Product>
  </Products>
</Company>