Magento Functions

Overview

Namespace urn:MagentoFunctions
Available since Zynk Workflow 2023.6.2

This article will outline how to implement the XSLT functions that we have made available for our Magento library. As shown below, you can call methods with or without a connection. If you do not specify a connection, the default connection will be used.

Please note, you must use a Magento V2 connection with this library, the Magento V1 library is not supported by XSLT functions.

You can make use of the Magento functions by including the following declaration in your XSLT document:

<xsl:stylesheet 
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    xmlns:MagentoFunctions="urn:MagentoFunctions"> <!-- define the MagentoFunctions argument -->

    <!-- transformation -->

</xsl:stylesheet>

Functions

The following methods can each be called with, or without, a connection identifier. If you do not provide a connection identifier, the default connection will be used.

The function will attempt to parse the connection identifier as a GUID (i.e the connection id), and if that is not successful, it will match to an existing connection based on the connection title.

• GetCustomer(string recordIdentifier)
• GetCustomer(string connectionIdentifier, string recordIdentifier)
• GetOrder(string recordIdentifier)
• GetOrder(string connectionIdentifier, string recordIdentifier)
• GetProduct(string recordIdentifier)
• GetProduct(string connectionIdentifier, string recordIdentifier)

Example

Input

<Data>
    <CustomerData>
        <Datum>
            <Id>5944</Id>
        </Datum>
    </CustomerData>
    <OrderData>
        <Datum>
            <Id>1</Id>
        </Datum>
        <Datum>
            <Id>2</Id>
        </Datum>
    </OrderData>
    <ProductData>
        <Datum>
            <Id>U21096</Id>
        </Datum>
    </ProductData>
</Data>

XSLT

<xsl:stylesheet 
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    xmlns:mf="urn:MagentoFunctions">

    <xsl:output indent="yes"/>

    <xsl:template match="/">
        <Company>
            <Customers>
                <xsl:for-each select="Data/CustomerData/Datum">
                    <xsl:call-template name="Customer"/>
                </xsl:for-each>
            </Customers>
            <Orders>
                <xsl:for-each select="Data/OrderData/Datum">
                    <xsl:call-template name="Order"/>
                </xsl:for-each>
            </Orders>
            <Products>
                <xsl:for-each select="Data/ProductData/Datum">
                    <xsl:call-template name="Product"/>
                </xsl:for-each>
            </Products>
        </Company>
    </xsl:template>

    <xsl:template name="Customer">
        <Customer>
            <xsl:copy-of select="Id"/>

            <!-- <xsl:variable name="MagentoCustomer" select="msxsl:node-set(mf:GetCustomer('', Id))"/> -->
            <!-- <xsl:variable name="MagentoCustomer" select="msxsl:node-set(mf:GetCustomer('c74eee9b-3d9b-45db-b7d9-cc784962c0e1', Id))"/> -->
            <xsl:variable name="MagentoCustomer" select="msxsl:node-set(mf:GetCustomer('Zynk Software Ltd (Magento v2)', Id))"/>

            <CompanyName>
                <xsl:choose>
                    <xsl:when test="count($MagentoCustomer/Errors/Error) &gt; 0">
                        <xsl:copy-of select="$MagentoCustomer"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="concat($MagentoCustomer/Customer/firstname, ' ', $MagentoCustomer/Customer/lastname)"/>
                    </xsl:otherwise>
                </xsl:choose>
            </CompanyName>
            <!-- <Dump>
                <xsl:copy-of select="msxsl:node-set($MagentoCustomer)"/>
            </Dump> -->
        </Customer>
    </xsl:template>


    <xsl:template name="Order">
        <Order>
            <xsl:copy-of select="Id"/>
            <xsl:variable name="MagentoOrder" select="msxsl:node-set(mf:GetOrder('Zynk Software Ltd (Magento v2)', Id))"/>

            <Name>
                <xsl:choose>
                    <xsl:when test="count($MagentoOrder/Errors/Error) &gt; 0">
                        <xsl:copy-of select="$MagentoOrder"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="$MagentoOrder/SalesOrder/increment_id"/>
                    </xsl:otherwise>
                </xsl:choose>
            </Name>
            <!-- <Dump>
                <xsl:copy-of select="msxsl:node-set($MagentoOrder)"/>
            </Dump> -->
        </Order>
    </xsl:template>

    <xsl:template name="Product">
        <Product>
            <xsl:copy-of select="Id"/>
            <xsl:variable name="MagentoProduct" select="msxsl:node-set(mf:GetProduct('Zynk Software Ltd (Magento v2)', Id))"/>

            <Name>
                <xsl:choose>
                    <xsl:when test="count($MagentoProduct/Errors/Error) &gt; 0">
                        <xsl:copy-of select="$MagentoProduct"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="$MagentoProduct/Product/name"/>
                    </xsl:otherwise>
                </xsl:choose>
            </Name>
            <!-- <Dump>
                <xsl:copy-of select="msxsl:node-set($MagentoProduct)"/>
            </Dump> -->
        </Product>
    </xsl:template>
</xsl:stylesheet>

Output

<?xml version="1.0" encoding="utf-8"?>
<Company xmlns:msxsl="urn:schemas-microsoft-com:xslt" xmlns:mf="urn:MagentoFunctions">
    <Customers>
        <Customer>
            <Id>5944</Id>
            <CompanyName>Joseph Harrison</CompanyName>
        </Customer>
    </Customers>
    <Orders>
        <Order>
            <Id>1</Id>
            <Name>1000073193</Name>
        </Order>
        <Order>
            <Id>2</Id>
            <Name>1000073194</Name>
        </Order>
    </Orders>
    <Products>
        <Product>
            <Id>U21096</Id>
            <Name>Nursery Wooden Mobiles - Springtime</Name>
        </Product>
    </Products>
</Company>